import QtQuick
import qs.config
import qs.services

Item {
    id: root
    readonly property var shortcuts: [
        { key: "Super + T", action: "Terminal" },
        { key: "Super + N", action: "Neovim in the current directory" },
        { key: "Super + W", action: "Web browser" },
        { key: "Super + F", action: "Files" },
        { key: "Super + I", action: "Panama Settings" },
        { key: "Super + Space", action: "Launcher" },
        { key: "Super + Grave", action: "Continuum overview" },
        { key: "Super + V", action: "Clipboard history" },
        { key: "Super + S", action: "Quick Settings" },
        { key: "Super + B", action: "Notifications" },
        { key: "Super + Shift + S", action: "Screen Intelligence" },
        { key: "Super + Shift + F", action: "Focus session" },
        { key: "Alt + H / L", action: "Previous / next workspace" },
        { key: "Alt + Shift + H / L", action: "Move window between workspaces" },
        { key: "Super + H / J / K / L", action: "Focus a tiled window" },
        { key: "Super + Shift + H / J / K / L", action: "Move a tiled window" },
        { key: "Super + Shift + X", action: "Send window to scratchpad" },
        { key: "Super + X", action: "Toggle scratchpad" },
        { key: "Print", action: "Capture, record, or read" }
    ]

    Flickable {
        anchors.fill: parent
        clip: true
        contentWidth: width
        contentHeight: content.implicitHeight + 64
        boundsBehavior: Flickable.StopAtBounds

        Column {
            id: content
            width: parent.width - 68
            x: 34
            y: 30
            spacing: 16

            Text { text: "Input & Shortcuts"; color: Theme.fg; font.family: Theme.fontFamily; font.pixelSize: 27; font.weight: Font.DemiBold }
            Text { text: "The Forge mental model, carried forward into native tiling."; color: Theme.fgDim; font.family: Theme.fontFamily; font.pixelSize: Theme.fontSize; bottomPadding: 6 }

            SettingsCard {
                title: "Panama shortcuts"
                Repeater {
                    model: root.shortcuts
                    SettingRow {
                        required property var modelData
                        required property int index
                        label: modelData.action
                        value: modelData.key
                        controlWidth: 210
                        divider: index < root.shortcuts.length - 1
                    }
                }
            }

            SettingsCard {
                title: "Hardware input"
                SettingRow {
                    label: "Mouse, touchpad, and keyboard devices"
                    detail: "Use Fedora's hardware-backed input panels"
                    divider: false
                    controlWidth: 126
                    SettingsButton { anchors.right: parent.right; anchors.verticalCenter: parent.verticalCenter; text: "Open keyboard"; onClicked: SystemSettings.openGnomePanel("keyboard") }
                }
            }
        }
    }
}